-
Notifications
You must be signed in to change notification settings - Fork 10
/
register.pl
172 lines (147 loc) · 5.14 KB
/
register.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
/* Part of SWI-Prolog
Author: Jan Wielemaker
E-mail: J.Wielemaker@cs.vu.nl
WWW: http://www.swi-prolog.org
Copyright (C): 2013, VU University Amsterdam
This program is free software; you can redistribute it and/or
modify it under the terms of the GNU General Public License
as published by the Free Software Foundation; either version 2
of the License, or (at your option) any later version.
This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
GNU General Public License for more details.
You should have received a copy of the GNU General Public
License along with this library; if not, write to the Free Software
Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307 USA
As a special exception, if you link this library with other files,
compiled with a Free Software compiler, to produce an executable, this
library does not by itself cause the resulting executable to be covered
by the GNU General Public License. This exception does not however
invalidate any other reasons why the executable file might be covered by
the GNU General Public License.
*/
:- module(register, []).
:- use_module(library(http/html_write)).
:- use_module(library(http/http_dispatch)).
:- use_module(library(http/http_parameters)).
:- use_module(openid).
:- use_module(library(smtp)).
:- http_handler(root(register), register, []).
:- http_handler(root(submit_registration), submit_registration, []).
register(Request) :-
http_parameters(Request,
[ for(Kind, [ oneof([wiki,news]),
default(wiki)
])
]),
site_user(Request, User),
reg_title(Kind, Title),
reply_html_page(
user(form(register(User, Kind))),
title(Title),
\reg_body(User, Kind)).
reg_title(wiki, 'Register to edit SWI-Prolog wiki pages').
reg_title(news, 'Register to manage news postings').
reg_body(User, Kind) -->
reg_explain(Kind),
form(User, Kind).
reg_explain(wiki) -->
html({|html||
<p>This form allows you to request permission to edit
the SWI-Prolog wiki pages. That is, the pages that have
an <b>Edit this page</b> in the <b>WIKI</b> menu.
</p>
<h2 class="wiki">Registration form</h2>
|}).
reg_explain(news) -->
html({|html||
<p>This form allows you to request permission to post
news articles using the menu <b>COMMUNITY/News</b>
</p>
<h2 class="wiki">Registration form</h2>
|}).
form(UUID, Kind) -->
{ http_location_by_id(submit_registration, Action),
PlaceHolder = 'Please tell us your plans, so that we can \c
tell you are a genuine human Prolog user',
site_user_property(UUID, name(Name), 'anonymous'),
site_user_property(UUID, email(Email), 'unknown')
},
html(form(action(Action),
[ input([type(hidden), name(kind), value(Kind)]),
table([ tr([ th([align(right)], 'Name'),
td(input([name(name),
placeholder(
'Name associated to commits'),
disabled(disabled),
value(Name)
]))
]),
tr([ th([align(right)], 'Email'),
td(input([name(email),
placeholder(
'Displayed with GIT commit'),
disabled(disabled),
value(Email)
]))
]),
tr([ th([align(right), valign(top)], 'Comments:'),
td([ class(wiki_text), colspan(2) ],
textarea([ cols(50),rows(10),name(comment),
placeholder(PlaceHolder)
],
''))
]),
tr([ td([ colspan(2), align(right) ],
input([ type(submit),
value('Sent request')
]))
])
])
])).
%% submit_registration(+Request) is det.
%
% Sent E-mail to submit a registration
submit_registration(Request) :-
site_user(Request, UUID),
http_parameters(Request,
[ comment(Comment, [optional(true)]),
kind(Kind, [])
]),
mail(UUID, Kind, Comment),
reply_html_page(
user(mailed(admin, permission(Kind))),
title('Mail sent'),
[ p([ 'A mail has been sent to the site adminstrator. ',
'You will be informed when the account has been ',
'created.'
])
]).
mail(UUID, Kind, Comment) :-
smtp_send_mail('jan@swi-prolog.org',
message(UUID, Kind, Comment),
[ subject('SWI-Prolog permission request'),
from('jan@swi-prolog.org')
]).
message(UUID, Kind, Comment, Out) :-
site_user_property(UUID, name(Name), 'anonymous'),
site_user_property(UUID, email(EMail), 'unknown'),
format(Out, 'New site permission request\n\n', []),
format(Out, '\t Kind: ~w~n', [Kind]),
format(Out, '\t UUID: ~w~n', [UUID]),
format(Out, '\t Name: ~w~n', [Name]),
format(Out, '\tE-Mail: ~w~n', [EMail]),
format(Out, '~n~w~n', [Comment]).
site_user_property(UUID, P, Default) :-
( site_user_property(UUID, P)
-> true
; arg(1, P, Default)
).
:- multifile
plweb:page_title//1.
plweb:page_title(user(form(register(_User, Kind)))) -->
{ reg_title(Kind, Title) },
html(Title).
plweb:page_title(user(mailed(To, permission(_Kind)))) -->
html('Mail sent to ~w'-[To]).